Cross Script Variables

A time may come when you will wish to have a repository to store variable values that can be read from and written to by any script. This article addresses a basic method for not only storing and retrieving non-float numeric values, but object references as well. This could prove very handy when creating dynamic game scenarios.

The Basics

A scenario for creating and testing this type of functionality includes at least three features:

1 - A script that acts as the database for storing values. In this article a Quest Script will be used to demonstrate this.

2 - A script that writes a value to one of the variables in the "database" Quest script when it is activated.

3 - A script that reads a value from one of the variables in the "database" Quest script when it is activated.

Using this basic model you should be able to easily construct a simple scenario to see this functionality in action.

The Quest Script

The quest script acts sort of like a very basic database. The next two scripts will demonstrate the command syntax for reading and writing to the quest script's variables from other scripts.

The script:

 Scriptname MyQuestScriptDatabase

 ref refVar ; reference values can be stored and retrieved

 float floatVar ; float values can be stored and retrieved

 short ShortVar ; integer values can be stored and retrieved

 begin GameMode ; begin block is not required

 ; you don't have to put anything in here
 
 end ; if begin block is not used the 'end' is not required either. 

Make sure you set the Script Type as "Quest" in the script editor window and then save your script.

The script is very simple. You just declare all the variables you need for storing values.

Notes

• If you assign starting values to your variables in the "database" script use a doOnce variable to keep the variables from being reset to their initial values on every frame refresh. Setting values within this script's Begin-End block without a doOnce will essentially "lock in" the values to their initial setting.

• The variable names listed in the script can be named whatever you like - preferably something meaningful to their purpose.

• You must declare a variable in the quest script and compile it BEFORE you can reference them in the read/write scripts described below. If you attempt to code your read/write commands and the variable has not yet been declared in the quest script you will receive a compiling error in your read/write script. (specifically this error message will state that your variable is an unknown variable or command even though you have declared the variable already within the read/write script.)

The next part of this step is to create a quest. You can read up on the steps for creating a quest on the wiki. Just keep in mind that the only setting needed for creating this functionality is the "Script" setting under the Quest Data tab. Once you create and name your quest select your quest script (as seen above) under the script setting for the quest. (For these examples the quest is named MyQuest.)

Notes

• You do not need to start the quest. The values within the quest can be written to and read from even if it is never started. However, if you set initial variable values in your Begin-End block then you will have to start the script at some time to set those values. Once set you can stop the script with StopQuest.

Storing a Value

Okay! Now that you have your quest and a quest script associated with it you need to know how to write values to it.

The script:

 Scriptname MyWritingScript

 ref refVar ; reference values can be stored and retrieved

 float floatVar ; float values can be stored and retrieved

 short ShortVar ; integer values can be stored and retrieved

 begin onActivate
 
   set MyQuest.refVar to ObjectReference ; or some reference variable

   set MyQuest.floatVar to 1234567890 ; or some float variable

   set MyQuest.ShortVar to 2012 ; or some integer variable

 end

That's it! Now associate this script with some object that can be "activated". When the player or an actor activates the object the values listed above will be assigned to the script variables in the quest script.

Reading a Value

Now that you know how to write values to your quest script database you just need to know how to read them.

The script :

Scriptname MyReadingScript

 ref refVar ; reference value as stored

 ref refVarRetrieved ; reference value as retrieved

 float floatVar ; float value as stored

 float floatVarRetrieved ; float value as retrieved

 short ShortVar ; integer value as stored

 short ShortVarRetrieved ; integer value as retrieved

begin OnActivate

set refVarRetrieved to MyQuest.refVar

set floatVarRetrieved to MyQuest.floatVar 

set ShortVarRetrieved to MyQuest.ShortVar

MessageBoxEx "See my reference: %n See my float: %g See my integer: %.0f", refVarRetrieved, floatVarRetrieved, ShortVarRetrieved
			
end

If you use this script exactly as written the message box will show the name of your reference rather than the reference. See MessageBoxEx for more. But the reference value is there and ready to use.

Practical Applications

So one might be wondering where functionality like this might prove useful. If you're just writing simple mods this type of functionality may seem a bit excessive. But take as an example a mod where the player will only belong to one faction (other than the player faction of course.) Oblivion is designed assuming the player might be a member of many factions. But what if your mod only allowed the player be a member of one faction? And what if the relationships between factions was absolutely critical to the playing out of the other scripts and behaviors in your mod? In this situation you might find yourself writing scripts where you would do a long series of repetitive checks like these:

if (player.GetInFaction FactionRef == 1)

These checks would go through each possible faction and could start to get a little hard on the eyes if there were a great many factions. This would make trouble shooting your scripts a bit more difficult too.

Using the functionality discussed in this article you could store the player's faction in a quest script and just retrieve it with a few lines of code each time a script needed the information! If the player's faction could switch you would just write code to change the value in the quest script for those situations.

Final Notes

• All the example scripts above are for basic concept testing. They are simplistic for the sake of study. Actual application would include additional content in each script.

• It is also possible to use an object script could be used in place of the quest script for the "database" feature. But the method is slightly different.

• It is possible for other variable types provided through the OBSE to be stored and retrieved using this system. For example, strings and arrays.

Additional Reading

• GetScriptVariable
• GetGlobalValue
• GetQuestVariable

The above articles should be read for reference purposes. Although not directly related it is valuable to note that these are only conditionals that appear to offer the functionality discussed in this article, but do not. Still, the syntax for reading and writing to a quest script was derived from notes found in these articles and so are worth reviewing.

See Also

• Quest scripts
• Global Scripts
• Global Scripts/Extended