MessageBox Tutorial
Intro
Most MessageBox mistakes are made when simple scripts are used as a base for more complex menu scripts. To prevent this, this tutorial will work towards a single all-purpose script that can be used and expanded for any situation. By the end, you will know the problems that can pop-up in a menu script, how to prevent them, and why every line of the all-purpose script is needed.
We'll start out with some of the basic mechanics of the MessageBox and related functions, followed by common mistakes in complex scripts, and then the all-purpose script and how to set it up. Finally, we'll go through how to use the script to easily move between multi-layered menus, and some extras that you can tack on to it.
Note that there are 4 mediums to attach a menu script to: Activators, Quests, Tokens (Object scripts on items in the player's possession), and Spells (or Magic Effect scripts). This article will focus mainly on activators, but the other methods, their differences, and how to set them up will be discussed on other pages. Activators are the focus as they are easier and safer to use in most situations (see "In which I try to convince you to use an activator" for the reasons, though it's highly suggested to read the article first).
Basic Mechanics of MessageBox and Related Functions
Every menu requires two functions: MessageBox to display the menu, and GetButtonPressed to return which button the player pressed. Follow the links for more details, but here are the important things to remember:
GetButtonPressed
- GetButtonPressed returns numbers from –1 to 9:
- -1 means no decision has been made
- 0 means the player selected the first option
- 1 for the second
- ...
- 9 for the tenth(you can have 10 options at most)
- GetButtonPressed will only return the correct button press the first time it's called in a script; any other use of GetButtonPressed will return -1. For instance, if the player presses the first button, then in the following script
if (GetButtonPressed == -1) ... elseif (GetButtonPressed == 0)
GetButtonPressed will return 0 the first time, move on to the 'elseif' test, and return –1 the second time.
To take care of this, set a variable to GetButtonPressed, and test the variable instead, as such:
short Choice ... set Choice to GetButtonPressed if (Choice == -1) ... elseif (Choice == 0)
Likewise, GetButtonPressed will return -1 for all following frames (until the script runs another messagebox).
Timing
MessageBox takes one frame to display, so you can use any block to display it. However, it can take up to 15 frames before GetButtonPressed will return the player's button press (even if the player presses the button on the same frame as the MessageBox function). Therefore, it needs to be in a block that runs every frame, such as GameMode, MenuMode, and ScriptEffectUpdate. It also needs to be on a script that is running every frame. For objects this means it must be in a Loaded cell, for quests this means fQuestDelayTime must be set to .001 and they must be running, and for spells this means the duration must be long enough (more on that in the Spell Menus subsection).
Keep 'em separated
Putting it all together, so far we end up with a script like this:
short Choice ... messagebox "Your menu" "Button 0" ... "Button 9" set Choice to GetButtonPressed if (Choice == -1) ... elseif (Choice == 0) ...
The problem with this script – every time it repeats while waiting for GetButtonPressed to return the player's button press, the MessageBox will be displayed again. To prevent this, you need to use a variable to keep them separated, as such:
short Choosing short Choice ... if (Choosing == -1) messagebox "Your menu" "Button 0" ... "Button 9" set Choosing to 1 set Choice to GetButtonPressed elseif (Choosing == 1) set Choice to GetButtonPressed if (Choice == -1) ... elseif (Choice == 0) ...
Note that both halves are required for each menu. To help keep things organized, you can set one to a negative number, and the other to a positive number, as in the above script.
Avoiding Common Mistakes for More Complex Menus
You won't want your menu script to run all the time, so it needs a clear beginning and a clear ending. On activators you can use the onActivate block and use ReferenceEditorID.Activate player, 1 to start the menu:
begin onActivate
messagebox "What would you like to do?" "Button 0" ... "Button 9"
set Choosing to 1
end
begin GameMode
if (Choosing == 1)
set Choice to GetButtonPressed
...
This works, but you will never be able to return to the first menu. To fix this, place the menu in the GameMode block. Set Choosing to -1 in the onActivate block to display the menu:
begin onActivate
set Choosing to -1
end
begin GameMode
if (Choosing == -1)
messagebox "What would you like to do?" "Button 0" ... "Button 9"
elseif (Choosing == 1)
set Choice to GetButtonPressed
...
To stop you can set Choosing back to 0. However, note that the GameMode block continues to run. To reduce the number of If tests run each frame use Return:
begin onActivate
set Choosing to -1
end
begin GameMode
if (Choosing == 0)
return
elseif (Choosing == -1)
...
set Choosing to 0 ;Whenever you want to exit the menu
Multiple menus require careful use of a governing variable to keep the menus separate. The most common error is to place the second menu within a button response, like this:
begin onActivate
messagebox "What would you like to repair?" "Armor" ... "Weapons"
end
begin GameMode
set Choice to GetButtonPressed
if (Choice == -1)
...
elseif (Choice == 0) ;Armor
messagebox "Which armor would you like to repair?" "Helmet" ... "Boots"
set Choice2 to GetButtonPressed
if Choice2 == -1
...
elseif (Choice2 == 0) ;Helmet
...
elseif (Choice2 == 9) ;Boots
...
endif
elseif (Choice == 9) ;Weapons
messagebox "Which weapon would you like to repair?" "Blade" ... "Bow"
...
If the player selects "Armor" from the first menu, the second menu ("Which armor would you like to repair") will be displayed, but any choice the player makes from the second menu will really be based on the first menu. For instance, if the player selects "Boots" in the second menu, the "Which weapons would you like to repair?" menu will be displayed.
Following the steps of the script, you can see why. The player will be shown the "What would you like to repair?" menu. They select "Armor". For a few frames GetButtonPressed sets Choice to -1, and nothing happens. About 15 frames after the player makes their choice, GetButtonPressed will return 0. This will bring up the second menu "Which armor...?". Choice2 will be set to -1, as the player hasn't read it yet. The player selects "Boots". Again, there will be several frames between the menu, and when GetButtonPressed returns the player's choice. This means the script will be running from the beginning of the GameMode block again. This time, Choice is set to 9 (because "Boots" was the tenth button), and the "Which weapon...?" menu is displayed.
To prevent this from happening, use the Choosing variable to keep menus separate:
begin onActivate
set Choosing to -1
end
begin GameMode
if (Choosing == 0)
return
elseif (Choosing == -1)
messagebox "What would you like to repair?" "Armor" ... "Weapons"
set Choosing to 1
elseif (Choosing == 1)
set Choice to GetButtonPressed
if (Choice == -1)
...
elseif (Choice == 0) ;Armor
set Choosing to -10
...
elseif (Choice == 9) ;Weapons
set Choosing to -11
endif
elseif (Choosing == -10) ;Armor
messagebox "Which armor would you like to repair?" "Helmet" ... "Boots"
set Choosing to 10
elseif (Choosing == 10)
set Choice to GetButtonPressed
if (Choice == -1)
...
elseif (Choice == 0) ;Helmet
set Choosing to 0 ;To exit
...
elseif (Choice == 9) ;Boots
set Choosing to 0 ;To exit
endif
elseif (Choosing == -11) ;Weapon
messagebox "Which weapon would you like to repair?" "Blade" ... "Blunt"
set Choosing to 11
elseif (Choosing == 11)
set Choice to GetButtonPressed
if (Choice == -1)
...
elseif (Choice == 0) ;Blade
set Choosing to 0 ;To exit
...
elseif (Choice == 9) ;Blunt
set Choosing to 0 ;To exit
endif
endif
end
Note that each menu has a pair of corresponding numbers: Main menu, -1/1; Armor menu, -10/10; Weapon menu, -11/11. When you set Choosing to the corresponding number, that menu will be shown. You can find more information in the MessageBox Tutorial#Moving Between Multiple Menus section.
Running the same choice for multiple frames
So far, we've been using GetButtonPressed like this:
...
elseif (Choosing == 1)
set Choice to GetButtonPressed
if (Choice == -1)
return
elseif (Choice == 0)
...
For 99% of what you'll do, this will work perfectly. However, let's say you need to scan through the player's inventory one item at a time:
...
elseif (Choosing == -1)
messagebox "What would you like to do?" "Count food" "Nothing"
set Choosing to 1
set Choice to GetButtonPressed
elseif (Choosing == 1)
set Choice to GetButtonPressed
if (Choice == -1)
return
elseif (Choice == 0) ;Count the number of food items in the player's possession
set InvPos to (InvPos + 1)
set pInvObj to (player.GetInventoryObject
if (IsFood pInvObj)
set FoodCount to (FoodCount + 1)
endif
...
elseif (Choice == 1) ;Nothing
set Choosing to 0 ;To exit
endif
...
"Count food" requires several frames to complete. Once GetButtonPressed returns 0, it will start off and test the first item. However, on the following frames GetButtonPressed will return -1, causing an infinite loop of if (Choice == -1) -> return. To prevent this, only run GetButtonPressed when it had previously returned -1:
...
elseif (Choosing == -1)
messagebox "What would you like to do?" "Count food" "Nothing"
set Choosing to 1
set Choice to -1
elseif (Choosing == 1)
if (Choice == -1)
set Choice to GetButtonPressed
elseif (Choice == 0) ;Count the number of food items in the player's possession
set InvPos to (InvPos + 1)
set pInvObj to (player.GetInventoryObject
if (IsFood pInvObj)
set FoodCount to (FoodCount + 1)
endif
...
elseif (Choice == 1) ;Nothing
set Choosing to 0 ;To exit
endif
...
Note that Choice is reset to -1 after displaying a menu. Otherwise, Choice would still be the same as for the last menu (0, in this case). GetButtonPressed would never be run because Choice isn't equal to -1, and that Choice (0) would run instead of the player's choice.
Creating Your New Menu
In which I try to convince you to use an activator
This is still being discussed. Feel free to join and share your thoughts and opinions on the Discussion page.
There are 4 mediums you could use for the script: Quest, Activator, Tokens (Object scripts on items in the player's possession), and Spells (or Magic Effect scripts). Each has their own advantages and disadvantages, but it's suggested you use an activator.
Activator Advantages
- Activators can keep persistent variables that other scripts can use (unlike tokens and spells)
- Quest variables can be reset by using 'StartQuest' when the quest is already running (and there are reports of quests requiring resetting if a variable is added in a mod's update).
- Activators are safe from Oblivion cell resets. These resets will return a container's inventory to it's original state, objects to their start location, etc., but the variables on the activator will remain the same.
- There's a clear beginning to it (OnActivate, unlike quests)
- It's easy and fast to start (harder for a quest)
- Tokens can randomly cause CTDs when removed (unless you wait for 5 frames first, and may cause other problems upon removal)
- Spells are difficult to manage
- Spells will only run in GameMode
- There will always be time inbetween menus, in which the spell's duration will decrease. Giving the spell a long duration can work, but is not a guarantee for multi-layered menus.
Activator Disadvantages
- They need to be Loaded to run every frame. The easiest way to keep it loaded is to set one of it's own variables every frame. Setting a variable loads an object into memory, as if it were in the same cell as the player. Like this:
short Working ... begin GameMode ... set Working to 1 ...
- Their script can run even when not around the player (though only for a single frame, but enough to cause problems). To solve this problem, set a flag variable (for this tutorial, Working) to 1 when the script should be running, and 0 when it should end. Use an if test to check Working, like so:
short Working
...
begin onActivate
...
set Working to 1
end
begin GameMode
if Working
if (Choosing == 0)
set Working to 0
...
endif
end
Set Working to 0 when you wish to keep the script from running.
- These solutions work hand in hand. When the script should be running, and Working is 1, set Working to 1 at the beginning of every frame to keep it loaded for the next frame. When it's 0, don't set any variables and the activator will be unloaded, preventing the script from errantly running. Combining them looks like this:
short Working
...
begin onActiavte
...
set Working to 1
end
begin GameMode
if Working
set Working to 1
if (Choosing == 0)
set Working to 0
return
elseif (Choosing == 1)
...
endif
endif
end
Other methods
What you'll need
You'll need to set up some objects for the next script: an invisible activator, an XMarker, and your own cell:
Your own cell
- Scroll down the "Cell View" window
- Select "TestQuset01"
- Right-click it
- Select "Duplicate Cell"
- Rename your new cell to something you'll remember (and don't worry about the lack of floors, it'll work just fine)
Activator
- Select an activator in the "Object Window"
- It needs to be an activator. Statics can't have scripts, NPCs and containers can cause a CTD if they have a scripted item in their inventory, and items can be picked up.
- Edit the name
- Press enter (or select ok in the edit menu)
- Click "Yes" when it asks if you want to create a new item
- Drag your new activator into the "Render Window"
- Right-click it
- Give it a "Reference Editor ID". This is the reference you'll use to start up the menu, so make it something memorable.
- Mark it as "Persistent Reference" and "Initially Disabled"
- Place the following script on your new activator
- Make the following script
- In the "Object Window", right-click your new activator
- Select Edit
- In the "Script" pull-down box, select "YourMenuScript"
Activator Script
scn YourMenuScript
Short Working
Short Choosing
Short Choice
Begin onActivate
Set Choosing to -1
Set Working to 1
End
Begin GameMode
If Working
Set Working to 1
If (Choosing == 0) ;meaning it shouldn't be running
Set Working to 0
;Add anything that needs to be re-initialized,
Elseif (Choosing == -1) ;Display your menu
Messagebox "Which option?" "First Option" "Second Option" ... "Tenth Option"
Set Choosing to 1
Set Choice to -1
Elseif (Choosing == 1) ;Catch the player's decision
If (Choice == -1) ;No choice yet
Set Choice to GetButtonPressed
Elseif (Choice == 0) ;First Option
;run your code for the first decision
Set Choosing to 0 ;to finish up
Elseif (Choice == 1) ;Second Option
;run your code for the second decision
Set Choosing to 0 ;to finish up
;...
; Elseif (Choice == 9) ;Tenth Option
;run your code for the tenth decision
; Set Choosing to 0 ;to finish up
Endif
Endif
Endif
EndYou can start your menus from any script with
YourActivatorsReferenceEditorID.Activate player, 1
.
Moving Between Multiple Menus
Review
As stated before, each menu has a pair of corresponding numbers. For clarity and to keep the two necessary halves of menus separate, those pairs of numbers have been set up a a negative number (i.e., -1) and a positive number (1). The negative number refers to the code that displays the menu:
...
if (Choosing == -1)
messagebox "What would you like to do?"
set Choosing to 1
...
while the positive number refers to the code to return the player's choice:
...
elseif (Choosing == 1)
if (Choice == -1)
set Choice to GetButtonPressed
elseif (Choice == 0)
...
You can start up any menu by setting Choice to the corresponding negative number:
set Choosing to -1
from anywhere else in the script.
If you're making multi-layered menus, you can use the numbers to know which layer you're on and the previous menu(s). For the first layer (the main menu), use the pair -1/1. For the branching menus, use -11/11, -12/12, etc. If menu -11 has more branches, set them to -111/111, -112/112, etc.
Each new layer gets an extra number. For example, a sub-branch from menu -12 would be -121. The number on the right refers to the sub-branch, while the numbers on the left refer to the menu they branched from. This is recursive, so in this example -121 is the first sub-branch from menu -12, and -12 is the second sub-branch from the menu -1.
Example script
Here's several examples of menu switching: (also, please note that due to wiki limitations, the messageboxes below have been given line breaks, whereas in the CS they would be on one line)
Short Working
Short Choosing
Short Choice
Begin onActivate
Set Working to 1
Set Choosing to -1
End
Begin GameMode
If Working
If (Choosing == 0) ;meaning it shouldn't be running
Set Working to 0
;Add anything that needs to be re-initialized,
Elseif (Choosing == -1) ;Display your menu
Messagebox "What would you like to donate?" "Gold" "Food" "Blood" "Cancel"
Set Choosing to 1
Set Choice to -1
Elseif (Choosing == 1)
If (Choice == -1) ;No choice yet
Set Choice to GetButtonPressed
Elseif (Choice == 0) ;Gold
Set Choosing to -11 ;to open the Gold menu
Elseif (Choice == 1) ;Food
Set Choosing to -12 ;to open the Food menu
Elseif (Choice == 2) ;Blood
Set Choosing to -13 ;to open the Blood menu
Elseif (Choice == 3) ;Cancel
Set Choosing to 0 ;to close the menus
Endif
Elseif (Choosing == -11) ;Gold menu
Messagebox "How much Gold would you like to donate?" "25"
"I've changed my mind" "I've changed my mind, I'll donate Food"
"I've changed my mind, I'll donate Blood"
"I've changed my mind, I won't donate anything"
Set Choosing to 11
Set Choice to -1
Elseif (Choosing == 11)
If (Choice == -1) ;No choice yet
Set Choice to GetButtonPressed
Elseif (Choice == 0) ;25
If (player.GetGold > 25)
Player.RemoveItem Gold001 25
Set Choosing to 0
Else
Set Choosing to -99 ;a message that the player doesn't have enough
Endif
Elseif (Choice == 1) ; I've changed my mind
Set Choosing to -1 ;to return to the opening menu
Elseif (Choice == 2) ; I've changed my mind, I'll donate food
Set Choosing to -12 ;to open the food menu
Elseif (Choice == 3) ; I've changed my mind, I'll donate blood
Set Choosing to -13 ;to open the blood menu
Elseif (Choice == 4) ; I've changed my mind, I won't donate anything
Set Choosing to 0 ;to close the menus
Endif
Elseif (Choosing == -12) ;Food menu
Messagebox "How much food would you like to donate?" "An apple"
"Two apples"
...
"Cancel"
Set Choosing to 12
Set Choice to GetButtonPressed
Elseif (Choosing == 12)
If (Choice == -1) ;No choice yet
Set Choice to GetButtonPressed
Elseif (Choice == 0) ;An Apple
If (player.GetItemCount Apple)
player.RemoveItem Apple 1
Else
set Choosing to -99 ;Go to special 'Not enough' menu
Endif
Set Choosing to -1 ;To return to main menu
Elseif (Choice == 1) ;Two Apple
If ((player.GetItemCount Apple) > 1)
player.RemoveItem Apple 2
Else
set Choosing to -99 ;Go to special 'Not enough' menu
Endif
Set Choosing to -1 ;To return to main menu
;...
Elseif (Choice == 9) ;Cancel
Set Choosing to 0
Endif
Elseif (Choosing == -13) ;Blood menu
Messagebox "How much blood would you like to donate?" "1 HP"
"2 HP"
...
"Cancel"
Set Choosing to 13
Set Choice to GetButtonPressed
Elseif (Choosing == 13)
If (Choice == -1) ;No choice yet
Set Choice to GetButtonPressed
Elseif (Choice == 0) ;1 HP
player.ModAV Health -1 ;don't actually use this, just an easy example
set Choosing to -1 ;to return to the main menu
Elseif (Choice == 1) ;2 HP
player.ModAV Health -2 ;don't actually use this, just an easy example
set Choosing to -1 ;to return to the main menu
;...
Elseif (Choice == 9) ;Cancel
Set Choosing to 0
Endif
Elseif (Choosing == -99) ;Player-doesn't-have-enough menu
Messagebox "You don't have enough."
Set Choosing to 99
Set Choice to GetButtonPressed
Elseif (Choosing == 99)
If (Choice == -1) ;No choice yet
Set Choice to GetButtonPressed
Elseif (Choice == 0) ;player pressed "Done", return to main menu
Set Choosing to -1
Endif
Endif
Set Working to 1
Endif
End
Extras
That will take care of most menu systems you'll ever want to create. However, there is still more functioniality you can add to your menus. From here, you can either get it all by using the following script, or pick and choose using the mini-tutorials:
Centalizing your decision catching
Running menus in both GameMode and MenuMode when your script is too large
Ensuring your menus are seen
Allowing the player to set a variable to any number
Controlling the menu system via external scripts
Applying it all
If you use want all of the above extras, your menu script will look like this: (due to wiki limitations, the large if test has been given line breaks, whereas in the CS it would all be on one line)
scn YourMenuScript
Short Working
Short Choosing
Short Choice
;GameMode and MenuMode variables
Short GMRun
Short ExitButton
;Ensuring Your Menu Is Read variables
Short MessageCounter
Begin onActivate
If (Choosing >= 0) ;Controlling the menu system via external scripts
Set Choosing to -1
Endif
Set Working to 1
Set MessageCounter to 0 ;Ensuring your menus are seen
If (MenuMode == 0) ;Running menus in both GameMode and MenuMode
Set GMRun to 1
Endif
End
Begin GameMode ;Running menus in both GameMode and MenuMode
If Working
If (Choosing == 0)
Set GMRun to 0
Set Working to 0
Set MessageCounter to 0 ;Ensuring your menu is seen
;Add anything that needs to be re-initialized
Elseif GMRun
Set GMRun to 0
Set ExitButton to 0
Messagebox "Exiting options..."
Elseif (Choice == -1) ;Ensuring your menus are seen
if (MessageCounter < 30)
set Choice to GetButtonPressed
if (Choice == -1)
if (MenuMode 1001 == 0)
if (MenuMode 1004 == 0) && (MenuMode 1005 == 0) && (MenuMode 1006 == 0) &&
(MenuMode 1010 == 0) && (MenuMode 1011 == 0) && (MenuMode 1013 == 0) &&
(MenuMode 1015 == 0) && (MenuMode 1016 == 0) && (MenuMode 1017 == 0) &&
(MenuMode 1018 == 0) && (MenuMode 1019 == 0) && (MenuMode 1020 == 0) &&
(MenuMode 1021 == 0) && (MenuMode 1024 == 0) && (MenuMode 1038 == 0) &&
(MenuMode 1039 == 0) && (MenuMode 1044 == 0) && (MenuMode 1045 == 0) &&
(MenuMode 1046 == 0) && (MenuMode 1047 == 0) && (MenuMode 1057 == 0)
set MessageCounter to (MessageCounter + 1)
endif
else ;MenuMode 1001
set MessageCounter to 0
endif
else ;Choice > -1
set MessageCounter to 0
endif
else ;Display menu again
set Choosing to -(Choosing)
set MessageCounter to 0
message "Trying menu again..."
endif
Elseif (Choice != ExitButton)
Set ExitButton to 0
Messagebox "Exiting options..."
Elseif (Choice == ExitButton)
Set Choosing to 0
Endif
Set Working to 1
Endif
End
Begin MenuMode
If Working
If (Choosing == 0)
Set GMRun to 0 ;Running menus in both GameMode and MenuMode
Set Working to 0
Set MessageCounter to 0 ;Ensuring your menu is seen
;Add anything that needs to be re-initialized
;Ensuring your menu is seen
;Centralizing your menu decisions
Elseif (Choosing > 0) && (Choice == -1) ;No choice yet
if (MessageCounter < 30)
set Choice to GetButtonPressed
if (Choice == -1)
if (MenuMode 1001 == 0)
if (MenuMode 1004 == 0) && (MenuMode 1005 == 0) && (MenuMode 1006 == 0) &&
(MenuMode 1010 == 0) && (MenuMode 1011 == 0) && (MenuMode 1013 == 0) &&
(MenuMode 1015 == 0) && (MenuMode 1016 == 0) && (MenuMode 1017 == 0) &&
(MenuMode 1018 == 0) && (MenuMode 1019 == 0) && (MenuMode 1020 == 0) &&
(MenuMode 1021 == 0) && (MenuMode 1024 == 0) && (MenuMode 1038 == 0) &&
(MenuMode 1039 == 0) && (MenuMode 1044 == 0) && (MenuMode 1045 == 0) &&
(MenuMode 1046 == 0) && (MenuMode 1047 == 0) && (MenuMode 1057 == 0)
set MessageCounter to (MessageCounter + 1)
endif
else ;MenuMode 1001
set MessageCounter to 0
endif
else ;Choice > -1
set MessageCounter to 0
endif
else ;Display menu again
set Choosing to -(Choosing)
set MessageCounter to 0
message "Trying menu again..."
endif
Elseif (Choosing == -1) ;Display your menu
Set ExitButton to 1 ;Running menus in both GameMode and MenuMode
Messagebox "What would you like to do?" "First Option" "Exit Menu"
Set Choosing to 1
Set Choice to -1
Elseif (Choosing == 1) ;Catch the player's decision
If (Choice == 0) ;First Option
;run your code for the first decision
Elseif (Choice == 1) ;Exit Menu
;run your code for the second descision
Set Choosing to 0 ;to finish up
Endif
;Allowing the player to set any number
short NumNewIngsDefault
elseif (Choosing == -2)
set ExitButton to -2 ;Running menus in both GameMode and MenuMode
messagebox "Set the default number of essences to be created.
(Currently %g)", NumNewIngsDefault,
"About 10 fewer (-12 to -8)"
"About 5 fewer (-7 to -3)"
"Default to that amount -2"
"Default to that amount -1"
"Default to that amount"
"Default to that amount +1"
"Default to that amount +2"
"About 5 more (+3 to +7)"
"About 10 more (+8 to +12)"
"Return to previous menu"
set Choosing to 2
set Choice to -1
elseif (Choosing == 2)
if (Choice == 0) ;10 fewer
set NumNewIngsDefault to (NumNewIngsDefault - 10)
set Choosing to -2
elseif (Choice == 1) ;5 fewer
set NumNewIngsDefault to (NumNewIngsDefault - 5)
set Choosing to -2
elseif (Choice == 7) ;5 more
set NumNewIngsDefault to (NumNewIngsDefault + 5)
set Choosing to -2
elseif (Choice == 8) ;10 more
set NumNewIngsDefault to (NumNewIngsDefault + 10)
set Choosing to -2
elseif (Choice == 2) ;-2
set NumNewIngsDefault to (NumNewIngsDefault - 2)
set Choosing to -1
elseif (Choice == 3) ;-1
set NumNewIngsDefault to (NumNewIngsDefault - 1)
set Choosing to -1
elseif (Choice == 4) ;Cancel
set Choosing to -1
elseif (Choice == 5) ;+1
set NumNewIngsDefault to (NumNewIngsDefault + 1)
set Choosing to -1
elseif (Choice == 6) ;+2
set NumNewIngsDefault to (NumNewIngsDefault + 2)
set Choosing to -1
elseif (Choice == 9) ;Return to previous menu
set Choosing to -1
endif
Endif
Set Working to 1
Endif
End