Scripting Tutorial: Summoned Creatures

This tutorial will help you set up a custom Summon Creature spell using the Script Effect system. This is a complete tutorial starting at the basics.

This will not change any game play settings or magic effects.

What you will do

This tutorial will show you how to:

• Create a simple holding cell
• Create persistent references: one for a MoveTo marker and one for your creature
• Create a Follow AI Package
• Configure a creature to be "summoned"
• Add a script to perform the "summon" effect
• Create a new spell with the scripted "summon" effect

Step 1: Create a holding cell for your creatures

• Open the World-> Cells menu and make sure the drop-down menu is set on Interiors.
• Right-click on a cell name and select New. Make sure your ID is something unique you can remember.
• Click Ok when done, and Ok again to close the menu.
• Double-click on your Interior under the Cell View listing. You will now drag in an anchor reference to move the creature back to the cell.
• In the Object Window, expand World Objects -> Static, and click on Architecture.
• Drag an interior such as “AnvilHouseMCInterior01” into the Render Window.
• Right-click on the architecture object in the Cell View Window listing, and select Edit.
• Enter a name for the reference such as “CreatureCageREF”,Set the Location to (0,0,10), select “Persistent Reference” and click Ok.

Step 2: Choose an AI follow package

There is a default “FollowPlayer” AI package, but it does not allow for swimming, falls, etc. You can use the steps below to create a custom package, or skip to Step 3.

• Open the Characters->Packages menu.
• Right-click on a space and select New.

Packages01.jpg

• Enter a unique name for you package that you can remember.
• Select “Must Complete” and “Defensive Combat” at a minimum; “Allow Swimming” and “Allow Falls” are optional. The other options are more for NPCs than creatures.
• Change the Package Type drop-down to “Follow”.
• Click on the Target tab and select “Specific Reference”.
• Choose the Cell “AbandonedMine02” and the Ref “Player PlayerRef”.
• Set the distance the creature can be from you: recommend 128.

Packages02.jpg

• Click OK when done.

Step 3: The Critter!

You will now change a normal creature into your summon version. I recommend editing an existing creature to ensure proper animation and models. For this example, I picked a Rat.

• In the Object Window, expand Actors->Creatures->Creatures. Scroll down to CreatureRat and double-click to open the properties window.
• Change the ID to “RatSummon01”, and the Name to “Summoned Rat”.
• Uncheck the “Respawn” box so we can control the resurrection from script.
• Click on the AI button to open the AI Object Dialog.

AIMenu01.jpg

• Set the “Aggression” to five(so if a friend of the creature or the creature itself is attacked, it will attack the posing threat) and delete any existing packages by selecting them in the list and pressing delete.
• Open the Character->Packages menu and drag either the “FollowPlayer” package, or a custom one made in step 2 into the AI menu.
• Click Save to close the menu. You can also close the Packages menu.
• Select the “Factions” tab and delete any existing factions(Not Required If NPC is Special). Open the Character->Factions menu and drag over the “PlayerFaction”.
• Click Ok and answer “Yes” to create a new form.
• Drag your new creature into the Interior you created. Set the Location to (0,0,10). Edit the creature reference just like the architecture piece and enter the reference editor ID “SummonRat1REF”.
• Select “Persistent Reference” and “Initially Disabled”. This ensures our creature is always available, but not moving around or running AI yet.
• Click Ok when done.

Step 4: Creating the script effect

This script uses the MoveTo command to perform the actual summoning of the creature to the player. The remaining code is for visual effects and placement of the creature back in the holding cell when done, or dead.

• Open the Gameplay->Edit Scripts menu and click Scripts->New.
• Copy the script and paste into the editor window. Be sure to change the reference names if different from the tutorial (lines 14, 33, and 74). These lines contain 3 numbers (0,0,10) which is the location of the reference, you can switch the reference location, but you must also switch the script location reference.

ScriptName SummonRatSCR

;This script can be used as a template for custom summoned creatures/NPCs

float timer
float fade
short playonce
ref SUMN

Begin ScriptEffectStart

;Set temp reference for scripting. 
;Allows faster transition of script as template. Also allows for leveled summon.
    set SUMN to SummonRat1REF
    ;Reset our creature if re-summoned before time runs out on spell                                            
    SUMN.disable        

    ;Now we move our creature to the Player
    ;Move the creature reference to the worldspace of the Player
    SUMN.moveto Player 30 30 10    
    ;Make our creature visible and active    
    SUMN.enable                        

    set fade to 1    ;Resets the alpha fade variable to 1

End

Begin ScriptEffectUpdate

    if ( timer > 30 )    ;Creature is dead and fade timer passed
        ;Move our creature back to its holding cell
        SUMN.kill
        SUMN.moveto CreatureCageREF 0 0 10 
        ;Reset our creature if dead
        SUMN.resurrect    
        ;Set our creature to an unprocessed state                            
        SUMN.disable                                    
    endif

    ;Adjust timer state for early fade/disable upon death
    if ( SUMN.getdead == 1 ) && ( timer < 28 )                
        set timer to 28
    endif

    if ( timer > 0.1 ) && ( playonce == 0 )
        ;Play effect for creature entrance
        SUMN.pms effectSummonMythicDawn 1            
        set playonce to 1
    endif

    
    ;Increment timer
    set timer to timer + GetSecondsPassed        


    if ( timer > 28 ) && ( playonce == 1 )
        ;Play effect for creature exit/death
        SUMN.kill            
        set playonce to 2
    endif

    if ( playonce == 2 )    
        ;Fade creature for exit/death                                            
        set fade to fade - 0.03
        SUMN.saa fade
    endif
        

End

Begin ScriptEffectFinish

    ;Move our creature back to its holding cell
    SUMN.moveto CreatureCageREF 0 0 10    
    ;Reset our creature if dead                        
    SUMN.resurrect        
    ;Set our creature to an unprocessed state                                        
    SUMN.disable                                                    

End

• Change the script type to “Magic Effect” in the drop-down and change the name if desired.
• Click the “Disk” icon (Save) when done, and exit the Script Editor.

Step 5: The Spell!

Now we put it all together. The script will simulate the summon effect, while the “Follow” package will make the new creature follow and fight for you.

• In the Object Window, expand Magic->Spells. Right-click on a spell name and select New.
• Give your spell a unique ID like “SummonRatCast”. Name the spell as desired, and select the type of spell (Spell, Lesser Power, or Power).("spell" is Recommended)
• Click on “Script Effect Always Applies” and deselect “Auto-Calculate”.
• Choose the minimum skill and set the cost to 0 and the charge to 0 if a Spell or LP.
• Right-click under “Effect Name” and select New.
• Select “Script Effect” under the Effect drop-down, and set the effect's duration to 30 (see the script notes on adjusting the spell length).
• Select your script from the script menu, and give the effect a name like “Summon Creature”.
• Finally, set the school to “Conjuration” and choose one of the default Summon spells for the Visual Effect.
• Click Ok twice when done to exit the spell editor.

Step 6: Getting your spell into the game

Adapted from Scripting Tutorial: My First Spell.

Setting Spell For Sale

Go to the object window. Maximize Actors, NPC, and Breton. Select male. click on a name listed and type (ed) quickly. Right click on EdgarVautrine, click Edit. Select the tab called spelllist. Do Not Close, go to object window maximize spells. Look for the spell you created. Move it to the EdgarVautrine spelllist. Click ok.

Find the Form ID (Not Necessary)

Go to the top of the spell list and find the "Count" column. Directly to the left of this column, you should see a double column line instead of the usual single line. Click and drag the right line of these double lines to the right to expand the "FormID" column. Now, scroll down and find the spell you just added. Write down the number in the Form Id column. It should look something like "01000ED9" (but may not be exactly that).

Save

This is important!

Choose File->Save from the menubar. If you were editing a new plugin, you will be prompted for a filename. Choose something memorable like "Summon Rat Spell".

Testing

Go ahead and start Oblivion up. When the launcher comes up, click on the "Data Files" button. Make sure that "Oblivion.esm" and the filename you chose earlier are both checked. Click "OK"

Teleport to The Imperial City Market District. Go to Edgar's Discount Spells. Buy The Spell From Edgar. If you followed the tutorial the cost of Buying the spell from Edgar should be $0.

Choose this spell from your spellbook and cast it.

You should now have a Rat following you!