A beginner's guide, lesson 7 - Using Scripts in Quests

TES IV: Oblivion Modding for Beginners

B. Scripts, Quests and NPC’s Lesson Seven: Using Scripts in Quests

Preamble

This is the Seventh in a proposed series of Tutorial Lessons aimed at teaching how to mod TES IV: Oblivion aimed at beginners. It will build up into a Complete Modding Course. Don't worry there are no exams, though there is some homework.

Files

I have uploaded some files which we will use to accompany the next few tutorials. It contains

A. BGModTutBase.esp This contains a building, a farmhouse, and a dungeon that we will use as sets in lessons 6, 7 and 8. This file is referred to in the text as the BASE files

B. BGModTutPlayTest.esp This is the interim quest mod illustrating the stage you should have reached prior to polishing the mod. This is referred to in the text as the PLAYTEST files

C. BGModAnvilCheat.esp: This is a small optional cheat mod to give users 5000 septims to allow them to follow this tutorial if they have not completed the quest. (See Introduction to lesson 4)

D. A RTF document containing the text for the first 7 lessons (as requested).

Download the files here.

Introduction

We have already begun building a quest. This lesson continues directly where Lesson 6 left off. We have set up a cottage which the PC will need to investigate to gain clues to identify who has stolen the deed and key. We have learned how to add dialogue using Topic/Response combinations and conditional statements to limit who gets to say the dialogue.

We have seen how to use a limited amount of scripting to progress our quest. While there is loads more dialogue to include in this part of the quest, we will focus far more on the use of scripting.

At the Cottage

We cannot rely on any information from NPC’s to progress our quest because the courier is dead.

We will first of all use the xmarkerheading object we placed in lesson 6 to identify when the PC gets close enough to trigger a stage bump. By placing the marker inside the cottage, you force the player to be in the cell before this gets triggered.

The next stage bump is done via another addition to the quest script. The quest script is used to add small conditional snippets that do useful jobs; In this case we are going to use GetDistance. This in common with all GET functions returns a numerical value. Some Get functions return values which are either 1 (Yes) or 0 (No). For example GetInFaction will return a 1 or 0 depending on whether the reference is in a particular faction or not.

The GetDistance function returns a numerical value which indicates how far away a reference is from a specified point. (Distance is measure in UNITS with one game unit roughly equal to 1.5 cm)

We will use the distance 300 which is fairly close to but not necessarily on top of the x marker we made. When the character gets close we want to move to stage 40. We can use the stage to limit when the active part of the script runs. We first need to add stage 40 in the stage tab. Now add this below the current IF-End if block inside the begin block of our quest script.

If (GetStage BGM001 == 30)
  If (Player.GetDistance BgCourierLodgeXMarker <= 300)
    SetStage BGM001 40
  EndIf
EndIf

In this case the quest stage acts as a DoOnce type control.

Now we need to write a bit of script to check if and when the player collects the two clues needed to allow Hubart to identify the criminal gang.

We have to set up a counter variable which I have called QObjectCount. (Type short). Each time a player adds one of the quest objects to their inventory we need to bump this counter by one.

We also want to know when each item is picked up so we can display a suitable message informing the player to keep looking. Again this is hand holding, and can be left out for a greater challenge and a deeper immersion.

We are going to write some script. Experienced scripter will throw their hands up at the clumsy nature of this bit of the script, but it gets the job done and I believe it is easier to follow the logic of why each line is added in this version.

Perhaps one of the greats will re-write this in a more concise form at some point.

So we declare the three variables to add to our variable list at the top of the script. You will notice that the list keeps growing as we find we need new variables.

Short Qobjectcount
Short Count1Once
Short Count2Once

We will add to the script already inside the current Begin GameMode block. We could always add a new Begin Block, but why add lines that we don’t need. Note the use of indents in an IF statement is purely for clarity and has no bearing on the running of the script.

We want this script to work if the amount of clues (QObjectCount) is less than 2. Once we have both we don’t want it to work.

So we set an IF condition

If (QObjectCount < 2)

Now we can use a nested IF statement. This is an IF statement within an IF statement. We will also use the && (AND) command. This combines IF conditions so that BOTH must be met for the first bit of script to work. If either or both fail the IF block moves on to any ElseIF, or Else statements. Otherwise it ends that block.

We want to check if the player has a copy of the BGPartialLetter in their inventory (GetItemCount) and that we have never checked this before(Count1Once). If this is true we add one to the clue counter (QObjectCount) and add one to the DoOnce counter Count1Once. This will stop the script from counting this item again the next time it runs (5 secs)

  If (Player.GetItemCount "BGPartialLetter" >= 1) && (Count1Once == 0)
    Set QObjectCount to QObjectCount + 1
    Set Count1Once to 1
  EndIf

We repeat this for the second clue item the BGEmbossedAmulet

  If (Player.GetItemCount "BGEmbossedAmulet" >= 1) && (Count2Once == 0)
    Set QObjectCount to QObjectCount +1
    Set Count2Once to 1
  EndIf

Finally, we add

EndIf

To finish this whole block

It should read.

If (QObjectCount < 2)

  If (Player.GetItemCount "BGPartialLetter" >= 1) && (Count1Once == 0)
    Set QObjectCount to QObjectCount + 1
    Set Count1Once to 1
  EndIf
  If (Player.GetItemCount "BGEmbossedAmulet" >= 1) && (Count2Once == 0)
    Set QObjectCount to QObjectCount + 1
    Set Count2Once to 1
  EndIf

EndIf

We now have the following bits of info in usable mathematical form.

We know when we have both clues - QObjectCount

We know when we have each individual clue - Count1Once and Count2Once

We want to display different messages depending on what combination of clues we have. There are four possibilities leading to four simple IF statements.

The values of the new variable MessageStage are just so we can clearly tell them apart.

I chose 100, 50, 25, and 10. It could be any number you like. You will need to declare the variable MessageStage first. Do this and then type this script, once again inside the Begin End block.

If (Count1Once == 0) && (Count2Once == 0)
  Set MessageState to 100
EndIf
If (Count1Once == 0) && (Count2Once == 1)
  Set MessageState to 50
EndIf
If (Count1Once == 1) && (Count2Once == 0)
  Set MessageState to 25
EndIf
If (Count1Once == 1) && (Count2Once == 1)
  Set MessageState to 10
EndIf

Now we use the message state to set the on screen message. This part of the script is very clumsy and can be cleaned up. We will do this in lesson eight.

Again we need to set some DoOnce variables to stop the messages being displayed again and again. I have called these DoM2Once etc.

The first message state can be ignored because we don’t need to prompt them again to search for clues.

If (DoM2Once == 0) && (MessageStage == 50)
  MessageBox "I have found a strange amulet. I should continue to look for clues"
  Set DoM2Once to 1
EndIf

If (DoM3Once == 0) && (MessageStage == 25)
  MessageBox "I have found a torn document. I should look for more clues"
  Set DoM3Once to 1
EndIf

The final situation does not require a MessageBox. As the quest journal can convey the message. But we do need to bump the quest stage. Again create stage 50 first.

If (DoM4Once == 0) && (MessageStage == 10)
  Set DoM4Once to 1
  SetStage BGM001 50
EndIf

This produces a stage bump. Add stage 50 and this journal entry.

I should now return to see Captain Hubart with these clues

Now we can now set up the next bit of interaction with Hubart.

We use the topic BGCluesFound that was added earlier. We want one response if the player has not collected the clues yet, and another for when they have collected the clue. We can use the quest stage as a condition. Set up the responses so that a new topic called BGRedRose is added if we have the clues.

TOPIC	BGCluesFound
RESPONSE	I recognise this amulet. It belongs to a gang of thieves called the Red Rose Brigade
CONDITIONS	GetIsId BGCptHubart == 1 GetStage BGM001 == 50
ADD TOPICS	BGRedRose
RESULT SCRIPT	(none)

TOPIC	BGCluesFound
RESPONSE	I need more clues to work with.
CONDITIONS	GetIsId BGCptHubart == 1 GetStage BGM001 < 50
ADD TOPICS	(none)
RESULT SCRIPT	* (none)

For the Red Rose topic add this response and add a new topic called BGSmith.

TOPIC	BGRedRose (Red Rose Brigade)
RESPONSE	They are a nasty bunch led by a couple of villains called Blair and Brown. I know they have a secret hide out in the mountains. Your best bet is to talk to an ex gang member by the name of Smith. I am surprised. I never took Brown for a killer.
CONDITIONS	GetIsId BGCptHubart == 1 GetStage BGM001 == 50
ADD TOPICS	BGSmith
RESULT SCRIPT	(none)

We can remove the quest clues as they are no longer needed.

Finally add the Brandy, if you wish. Alternatively we could omit this and allow the player to make his choices

TOPIC	BGSmith (Smith)
RESPONSE	Yeah, he quit the gang a while back. you'll find him hanging out at the Aleswell Inn. He's partial to a drop of Brandy. That might help loosen his lips. I take back the cottage key and hold on to this document.
CONDITIONS	GetIsId BGCptHubart == 1 GetStage BGM001 == 50
ADD TOPICS	BGRedRoseBrigade
RESULT SCRIPT	Player.Additem "PotionCyrodiilicBrandy" 1 Player.RemoveItem "BGPartialLetter" 1 Player.RemoveItem "BGCourierKey" 1 Player.RemoveItem "BGEmbossedAmulet" 1 SetStage BGM001 60

To complete this section we need to update the journal and move on to Aleswell.

Add this to the Stage 60 journal entry.

I should travel to Aleswell and talk to ex Red Rose Gang member Smith. He may be able to help me locate the gangs hide out

Aleswell Phase

Objectives: This is the last section prior to the big show down. We want to set up a disposition based dialogue in which Smith, once he likes you enough, will give you the location and key to the hidden Red Rose Brigade cave system.

We need to create

• Hideout Key
• NPC called Smith
• Map marker to the exterior of the Cave system
• The Cave system (if you are not using the base files)

First we want set up our NPC.

We need this so we can add a quest target.

I used a member of the thieves guide as a base. I again stripped out his AI, but I left him as a member of the thief’s guild. This will help fellow guild members get a bit of a boost to their disposition.

I have chosen Aleswell as a set for this part of the quest because it is actually a lousy location to use. Aleswell is the setting for an interesting Miscellaneous Quest. In this quest all the inhabitants of the town are invisible. If the user has completed this quest before they load this mod, they will be no problem. However, if this id the first time a player has entered the in, they will find themselves immediately involved in this quest. We need to make sure our mod interacts with this quest.

We could of course use some scripts (see lesson 8) that hides Smith in amongst the invisible folk until you solve this one. This in effects gives our quest a bit of a bonus making our storyline even longer.

But as is so often the case, the simplest solution, is to just brush over it with a quick bit of dialogue.

We can set up a GREETING for Smith. Here we use the quest stage for the miscellaneous quest called MS47 Zero Visibility. This is the stage where the people of Aleswell become visible.

TOPIC	GREETING
RESPONSE	This is so weird. Everyone is invisible. I came here to blend in with a crowd. Just my luck
CONDITIONS	GetIsId BGMSmith == 1 GetStage MS47 < 50
ADD TOPICS	(none)
RESULT SCRIPT	(none)

The next bit of the quest is a bit tricky.

First let’s review what we want to do.

We are going to set up a situation in which Smith is reluctant to tell us any information regarding the hideout until he likes us enough.

This is called an Information refusal. We can set up the refusal very easily.

Let’s do that now.

TOPIC	BGRedRoseBrigade
RESPONSE	I don't know you, and I don't think I want to talk to you about them
CONDITIONS	GetIsId BGMSmith == 1 GetDisposition < 90
ADD TOPICS	BGBrandy
RESULT SCRIPT	(none)

We then check the Info Refusal flag.

This means this topic can be revisited and the response will be re-evaluated.

As long as the disposition to the player is less than 90, Smith will give us the brush off when we talk about the Red Rose Brigade.

Somehow we will need to get that disposition up. If the PC is a member of the thieves guide that will help. We can bribe the NPC or play the disposition game. Of course PC’s with good speech craft will also get a bonus. However, I have deliberately set the threshold high because I want to use the BRANDY idea we set up in Chorrol.

Designing an Object Script

The first bit of scripting we did was to overcome the lack of an NPC to progress our quest. This time the problem is a little less clear. We want to set the game up so that giving some Brandy to Smith that boosts his disposition towards us.

It is no great chore to add a choices response to the Brandy topic.

Choice 1 – Gives him the brandy and bump disposition via a result script
Choice 2 – Refuses to give him brandy.

This is how I initially set it up. However there are two big problems with this solution.

The first problem is that it is a one time only action. You can’t keep giving him Brandy because the result script as we have set up the quest only allows this script to run once.

The second problem is more serious. If we give him some Brandy we have to remove it from the players inventory. But what happens if the player does not have any Brandy in his inventory? Perhaps he drunk the supply Hubart gave him, or sold it, or put it in a safe place and forgot it. The RemoveItem function does not check if an item is there. If it is not the item is removed and the inventory is set at -1.

This is not a good situation. Of course the player can reset it to zero by obtaining some more Brandy, but it is messy. It also is silly that the player hands Smith a bottle of Brandy when he hasn’t got one.

We need to have some kind of if statements that check the Brandy is in the inventory, and another option to offer more.

The solution is to Script this. Here is a working script that does this. We can use a bit of dialogue to set the value of the variable BrandyTalk. Before we look in detail at the script. Take a look through it. Try to work out what each bit is doing. This is a great way to learn scripting. Scour the forums for examples of scripts and try to work out what is happening.

Scriptname BGM001SmithScript

Short DoOnce
Short Button
Short BrandyTalk
Begin GameMode

If (BrandyTalk == 1) && (GetStage BGM001 == 60)
  If (Player.GetItemCount "PotionCyrodiilicBrandy" >=1)
    If (DoOnce==0)
      MessageBox "How many Bottles of brandy would you like to give to Smith",
        "None", "One", "Two", "Three", "Four" ;note that this should not
			; be returned, it is only because of page width problems that it is.
      Set DoOnce to 1
    EndIf
  EndIf
Else
  Return
EndIf

If (DoOnce == 1) && (GetStage BGM001 == 60)
  Set Button to GetButtonPressed
EndIf

If (Button >= -1) && (GetStage BGM001 == 60)
  If (Button == 0)
    Set BGM001.BrandyTalk to 0
    Return
  EndIf

  If (Button == 1)
    If (Player.GetItemCount "PotionCyrodiilicBrandy" >= 1)
      Player.RemoveItem "PotionCyrodiilicBrandy" 1
      BGMSmithRef.ModDisposition player 15
      Set BrandyTalk to 0
    Else
      Message "You don't have enough Brandy"
    EndIf
  EndIf

  If (Button == 2)
    If (Player.GetItemCount "PotionCyrodiilicBrandy" >= 2)
      Player.RemoveItem "PotionCyrodiilicBrandy" 2
      BGMSmithRef.ModDisposition player 30
      Set BrandyTalk to 0
    Else
      Message "You don't have enough Brandy"
    EndIf
  EndIf

  If (Button == 3)
    If (Player.GetItemCount "PotionCyrodiilicBrandy" >= 3)
      Player.RemoveItem "PotionCyrodiilicBrandy" 3
      BGMSmithRef.ModDisposition player 45
      Set BrandyTalk to 0
    Else
      Message "You don't have enough Brandy"
    EndIf
  EndIf

  If (Button == 4)
    If(Player.GetItemCount "PotionCyrodiilicBrandy" >= 4)
      Player.RemoveItem "PotionCyrodiilicBrandy" 4
      BGMSmithRef.ModDisposition player 60
      Set BrandyTalk to 0
    Else
      Message "You don't have enough Brandy"
    EndIf
  EndIf
EndIf

End

We attach this script once compiled to the NPC character BGMsmith using the script box in the character interface.

Let’s look more closely at this script. We use the top section to declare variables.

The script is broken into 3 sections contained in a Begin GameMode Block.

Firstly

  If (BGM001.BrandyTalk == 1) && (GetStage BGM001 == 60)
    If (Player.GetItemCount "PotionCyrodiilicBrandy" >= 1)
      If (DoOnce==0)
        MessageBox "How many Bottles of brandy would you like to give to Smith",
          "None", "One", "Two", "Three", "Four" ;should not return
        Set DoOnce to 1
      EndIf
    EndIf
  Else
    Return
  EndIf

(Note the MessageBox statement should all be on one line, it is only the result of wrap around text in this document that produces the look above . It should be

MessageBox "How many Bottles of brandy would you like to give to Smith", "None", "One", "Two", "Three", "Four"

This is the control part of the script. It checks that a number of conditions are true. Firstly it checks the status of a variable called BrandyTalk. We set this to 1 using a conversation between the PC and Smith. Until this happens the script will fail it conditions and skip to the

  Else
    Return

This terminates the script and prevents any further processing.

The second check is the GetStage check. This will prevent the script from running later in the quests progress.

If we have talked to Smith about Brandy, the core bit of this check runs.

  If (Player.GetItemCount "PotionCyrodiilicBrandy" >= 1)
    If (DoOnce == 0)
      MessageBox "How many Bottles of brandy would you like to give to Smith",
        "None", "One", "Two", "Three", "Four" ;should not return
      Set DoOnce to 1
    EndIf
  EndIf

We again carry out some relevant tests. The first checks that the player does indeed have Brandy in his inventory. This uses the GetItemCount function. We then set up a DoOnce loop to prevent the message box from being displayed again and again.

MessageBox is one of the two communication functions. It displays the text in the form of a pop-up box which will also produce a number of labelled buttons. We will look in more detail at some other functions of MessageBox in a later lesson.

The second block will only run once the value of DoOnce has been set to one in the above block

  If (DoOnce == 1) &&(GetStage BGM001 == 60)
    Set Button to GetButtonPressed
  EndIf

GetButtonPressed returns a value equivalent to the ‘buttons’ position in the message box list. It is normally set at -1 but takes the values 0-9 depending on the button selected.

MessageBox "Some Message that appears in the Box”, Option A, OptionB, OptionC

• OptionA selected GetButtonPressed=0
• OptionB selected GetButtonPressed=1
• OptionC selected GetButtonPressed=2

The value selected and assigned to the variable Button is then used in the third part of the script.

This is a little longer. It begins with a check that we have assigned a value by pressing the button.

  If (Button >= -1) && (GetStage BGM001 == 60)

Then we move onto the working parts of the script.

If we select none, the script resets the value of BrandyTalk and DoOnce to zero. We are then able to use the script again later.

  If (Button == 0)
    Set BGM001.BrandyTalk to 0
    Set DoOnce to 0
    Return
  EndIf

If we select one bottle. Then the next bit of script checks if we have enough brandy in our inventory to give Smith one bottle. It takes the bottle from your inventory. It then increases Smiths Disposition towards you by 15.

Finally It resets the control variables to allow the script to run again later. Note in this version we don’t actually give Smith the brandy. There is no technical need to do so.

If you don’t have enough you get a message and then it resets the controlling variables.

  If (Button == 1)
    If (Player.GetItemCount "PotionCyrodiilicBrandy" >= 1)
      Player.RemoveItem "PotionCyrodiilicBrandy" 1
      BGMSmithRef.ModDisposition player 15
      Set BGM001.BrandyTalk to 0
      Set DoOnce to 0
    Else
      Message "You don't have enough Brandy"
      Set BGM001.BrandyTalk to 0
      Set DoOnce to 0
    EndIf
  EndIf

The remainder of the script is a repeat of this for the options 2 bottles, 3 bottles, and 4 bottles.

The trick with any script is to exercise some control over when the script runs. We are controlling this script using a key quest variable called BrandyTalk. Before we can compile our script we will have to add this variable to the quest script.

We adjust its value using topics called BGBrandy, BGBrandyChoice1, and BGBrandyChoice2

TOPIC	BGBrandy
RESPONSE	Yeah, I love the stuff. Have you any to spare?
CONDITIONS	GetIsId BGMSmith == 1 GetStage BGM001 == 60
ADD TOPICS	(none)
CHOICES	BGBrandyChoice1 BGBrandyChoice2
RESULT SCRIPT	(none)

We can then use the choices to set our control variable to 1.

But the problem still remains that this result script will only be carried out once.

The solution is simply to make copies of the response and use another variable to increment through them so that each one becomes valid.

You can do this as many times as you like.

I settled for 4. I think it is unlikely you will need more than three turns but the option is there.

Add another quest variable to the quest script called DoNextBrandy

TOPIC	BGBrandyChoice1(Yes, I might have)
RESPONSE	I think I might warm to you.
CONDITIONS	GetIsId BGMSmith == 1 GetStage BGM001 == 60 GetQuestVariable BGM001.DoNextBrandy == 0
ADD TOPICS	(none)
RESULT SCRIPT	Set BGM001.BrandyTalk to 1 Set BGM001. DoNextBrandy to 1

The second response info reads

TOPIC	BGBrandyChoice1(Yes, I might have)
RESPONSE	I think I might warm to you.
CONDITIONS	GetIsId BGMSmith == 1 GetStage BGM001 == 60 GetQuestVariable BGM001.DoNextBrandy == 1
ADD TOPICS	(none)
RESULT SCRIPT	Set BrandyTalk to 1 Set DoNextBrandy to 2

Add another couple of responses, make all of them goodbyes using the Good bye flag. this ends the dialogue automatically, closes the topic menu and forces the now active script to run.

We also need to add a negative response. Note there is no result for this one, and you don’t need to make it a goodbye.

TOPIC	BGBrandyChoice2 (No sorry I’m out)
RESPONSE	Pity, I might have liked you more if you did.
CONDITIONS	GetIsId BGMSmith == 1 GetStage BGM001 == 60
ADD TOPICS	(none)
RESULT SCRIPT	(none)

By a combination of speech craft, factions, bribes disposition games and brandy gifts the Player should be able to raise the disposition to 90 eventually. This will trigger the next bit of dialogue and send us towards the quest climax. Return to the BGRedRoseBrigade topic and add this

TOPIC	BGRedRoseBrigade
RESPONSE	Ok, the truth is I've fallen out with the gang. They've threatened to kill me for leaving. You look like you can take care of them. Watch out for Blair he is a nasty bit of work. Here's the hideout key, and I'll mark the hideouts location on your map. Mind you I am surprised at Brown. He was a decent chap when I was in the gang.
CONDITIONS	GetIsId BGMSmith == 1 GetStage BGM001 == 60 GetDisposition >= 90
ADD TOPICS	(none)
RESULT SCRIPT	SetStage BGM001 70

We can then use the result script to bump the stage to 70

In the quest stage section for stage 70 we can add an appropriate journal entry and a quest stage result script to add a key and activate another map marker. Of course before we do this we need to add the MapMarker to the exterior of our cave. The cave system cell is BGmodtSugglersCaveCOPY0000 in the Interiors worldspace. The cave exterior cell is BGTutMCaveExt in the Tamriel worldspace.

Again we can use the door teleport marker to get ourselves to the exterior location. Drop in a MapMarker and give it a Suitable reference name like BGCaveMapMarker.

Journal entry

Smith has given me a key for the Red Rose Brigades hideout. I should go to the hideout and see if I can recover my uncle's Key and House Deed.

RESULT SCRIPT

• Player.Additem "BGHideoutKey" 1
  ShowMap BGCaveMapMarker

Red Rose Hideout Phase

Objectives: This is the climax of our quest. The player will travel to a cave/dungeon, and will finally have his show down with the boss villain. We also want to set up a treasure chest as an additional reward. To make the players task a little harder, we will need to add some goons to fight along the way.

We will need

• Dungeon/Cave system
• Letter, adding extra clue from Brown about chest
• Several NPC goons
• NPC called Brown
• NPC called Blair
• Key to Browns cell
• Key to House
• First Deed Document
• A special chest.
• Some traps etc.

Dungeon Design Ideas

The first thing we will need is a cave system or Dungeon for the player to delve. The dungeon pieces are a little harder to work with compared to the standard building interiors, as they are not complete pieces. Instead they slot together, piece by piece to create whole rooms.

A lot of the CS building parts work this way. Castles, Large Basements, Caves, ruins, and Dungeons are all created using this slotting method. Firstly make sure you switch on the snap to guides and the angle rotation guides, it makes life easier. Then open files/preferences and alter the snap to value to 1.

This alters the sensitivity of the snap, giving a closer fit.

Again the best source of information and design ideas is the game and the CS. You should by now of got into the habit of making note of ‘cool’ locations and looking them up in the CS.

The cave system I have set up for this tutorial, was created in a hurry. I simply visited other cave systems in the CS, and cut and pasted chambers that I then linked together.

It’s funny how you can come full circle. I now realise that the problem with the My First Dungeon tutorial in the Wiki is that it choose to illustrate its techniques using a dungeon. Had the Wiki went for my first house instead, it would have been much better off. However, we now know what we are doing, and working dungeons should be no problem.

As I have said the tutorial's dungeon supplied in the files is not the greatest dungeon in the world. Far from it. It is a simple multi chamber linear cave system. This means the PC has very little choice how he progresses. He must make his way through each room, and face each challenge. This is both an advantage and a disadvantage. If I was building this cave system for ‘Full Mod’, I must admit I would have spent much more time on it.

It would for instance have been nice to give players alternative paths, so those who prefer to avoid ‘hack and Slash’ trawling could sneak pat a few goons. Of course you would then have to set up a few more traps to keep them on their toes. One of things I have been disappointed about has been the lack of intelligent traps in Oblivion. By that I mean traps and puzzles where you have to stop and think of a solution. The game mechanics don’t easily lend them selves to this but it is a shame.

I don’t intend to give you a click by click, bit by bit guide to building dungeons. If you get stuck use the PLAYTEST version as a guide.

Dressing the Dungeon

Okay, let’s add some bits to help move our story forward. First let’s add an Xmarkerheading close to the interior door. We can then use the marker as a reference in an addition to our growing quest script.

  If (GetStage BGM001 == 70)
    If (player.GetDistance BGRRCaveMarkerRef <= 300)
      SetStage BGM001 80
    EndIf
  EndIf

We can also update the Journal

I've Arrived at the Red Rose Brigades Hideout. I will need to move cautiously. I need that house key.

Although this first chamber is quite large, I have decided to limit the threat to a single small random creature, a rat or a crab (LL0NuissanceBeast100). Why? Two reasons I want to be able to escalate my threat and I want to build suspense.

One of the design choices you will have to make is how to balance threat against reward. You should also try to escalate the threat as the story progresses. For instance it would be very easy to throw five or six deadra into the first chamber of our dungeon. However, the question is then where do we go from there. If you start with too big a threat then, you have little room to escalate that threat later. Also try to give a little thought to the user who has minimum specifications. I’ve seen a few works in progress where they have designed a really cool crypt with 30 or so monsters in it. But I know that on my poor little PC, I’ll get a frame rate of about 3 frames a week. Consequently this is not a mod I’ll be playing. Bigger doesn’t mean better, more is sometimes less.

The player is also expecting to meet bad guys, hopefully he will edge his character down into the first chamber fully expecting an army of trolls. I want to disappoint him. I want him to start to think this is easy before we hit him/her with the big stuff.

I also want to set the scene a little. For this I created another corpse, and placed near it a letter which informs them about the special treasure chest and Brown's imprisonment.

Make a corpse and the letter. Don’t give the corpse too much inventory, after all this is a freebee. I also added a leveled nuisance creature at the far end of the chamber; this should allow the PC to get to the corpse and then have to deal with the annoyance of a one hit kill creature.

The text for the letter is

<br>
<font face=5><br>
Dear Smith,
<br>
<br>
I beg of you, please help me. Blair has gone mad. I have been imprisoned<br>
<br>
It all began when we attacked the White Horse Courier near Chorrol.
It was supposed to be a simple robbery. But when Blair found that the only treasure
was a key to a house and a deed which had to be registered in the Imperial City he went beserk. 
<br>
He killed the courier in cold blood. I wanted no part of it.<br>
I suggested the gang might do better with me in charge. He accused me of being a
member of our rivals, the Torch Gang. Now he's had me locked up because I know how
to open his treasure chest. He wants to  kill me but he fears the other gang members
might turn on him.
<br>
Please Smith, send help.I have asked one of gang member loyal to me to take this
letter to you. I hope he makes it. Blair is watching my every move.
<br>
<br>
Your old friend,
<br>
Brown

We make and add the following script to the letter

Scriptname BGM001BrownScript

Begin OnAdd Player

  If (GetStage BGm001>= 80)
    SetStage BGm001 90
  EndIf

End

Again we can bump the stage and enter another journal entry for stage 90

I have found a letter from Brown. It appears the Red Rose leader has imprisoned him. Brown has knowledge of a secret treasure. I should try to talk to him.

Finally I messed about with the lighting, to try to create a little more atmosphere. Clearly caves should be darker than the normal world. Try to use spot lights to pick out the bit you want the PC to see and to hide threats you want to be a surprise.

The second chamber will contain a single NPC. We want all the Red Rose Brigade NPC’s to act as a team. How? Factions are the answer.

Factions

Factions are used in three ways by the game. Firstly they are used to establish a hierarchy or internal structure for organisations the PC can join. Secondly they are used to group NPC’s into teams with similar behaviours; these teams will act to protect each other when threatened. The final use of factions is to collect NPC’s together to allow grouped conditions statements.

To create a new faction opens up the faction box from the menu. In the column on the left is a list of all the existing factions. Rick click and select new. Give the Faction a unique name. Say BGRedRoseBrigade. Now, add a name to the top. Red Rose Brigade.

The flag at the top which reads hide from player, basic controls whether or not a player can enter the faction or not. Leave this as hidden.

The central box controls the ranks and titles within the faction. Note the ranks are split to offer the choice of alternative titles based on gender. In the case of our faction these have no meaning at all. However, since this is only chance we will get to look at lets set up a simple three tier structure for practice.

The final box at the bottom is the most useful.

It controls the disposition of a group to other factions or groups. Again it’s the standard right click new to add a group from the existing list into the disposition modifier box. You need add a numerical modifier ranging from +100 to -100. This modifier is applied to all members of the group.

The results are cumulative. Let’s say we decide that the Red Rose Brigade is closely affiliated with the various Bandits who occupy Tamriel. We can add a modifier of say (+) 70 to that group. Rick click select new, scroll down and find Bandit faction. Select it. Now alter the modifier to 70. From now on every member of the Red Rose faction will add 70 to there disposition towards bandits. We can add as many groups as we like.

We want the Red Rose member to be openly hostile to the PC. This is achieved because there is a faction called the PlayerFaction which has a solitary member, the PC. We can adjust the Red Rose disposition for this faction to -100. This means they will hate us and attack on site.

Create an NPC. I used the BanditMelee character as a base Template. This character already comes with leveled armour etc. Although the will appear to be naked in the render window.

I also popped in a chest, renamed it so I could alter it contents and add a few coins. The level of a NPC is controlled by the flags and boxes to the left of the character box.

We can make two choices.

Level to a value: In this option we select a pre ordained level for the NPC. The advantage is that we can control how tough a NPC is, and therefore the challenge set by that enemy. This is ideal if we have a particular reward which we feel should be earned by high ranking, or indeed low ranking PC’s. Suppose you design a one hit kill sword. This is a big reward. The player should have to earn this reward by defeating a big boss.

Equally, perhaps the reward is a few coins. Then it may be appropriate to set a simple challenge.

The disadvantage is that if you set an NPC at level 40, only a small number of players will meet this challenge, and many may simple unplug your mod.

Level against PC: This is one of the more controversial developments in Oblivion. Many Morrowind veterans have been particularly vocal in their criticism of this technique. The advantage is that no matter what level your PC is at you will meet a decent challenge which will test your PC. It allows access to all PC’s and does not exclude any. However, it has disadvantages as well. This approach does mean that some times the risk does not match the reward.

For this tutorial I have chosen to use the Level against PC method as this is the Oblivion norm. It is of course a matter for each designer to choose. I would suggest that what ever method you choose is consistent through out the mod. If you mix and match you could have the situation where the first goons is 10 levels above your boss, or a situation where after defeating a series of level 2 goons you suddenly encounter a level 30 boss.

We also want this first goon to be a little bit easier than those coming up so lets set the value to -2 levels. Using the offset box. The bandit already has a suitable leveled inventory.

The main central chamber will contain 3 NPC’s. Again add the Red Rose Faction to their faction list and delete the others. I used more bandits as a base for these.

I also set the offset at -1.

Finally I messed around with the lighting a bit. I wanted to give a stealthy player a chance. I remove the lighting from the linking corridor and close to the entrance.

The Final Chamber

This consists of a large chamber with two ante chambers. In the first ante chamber we create a cell by placing a door in the corridor. We can use this to house NPC BGBrown. I used the Bandit Boss as a model, but removed his factions.. Remember do not make Brown a member of the faction.

Final we create Blair. He is our Boss. I made him +2 above the PC. I am going to say very little about this PC, because here is where you get to have the most fun making your own bad guy. Once created

Add the key to Browns cell door. Make the cell door, locked and set it to ‘Needs a key‘.

You will also need to set up the Prize house. Go to the interior cell BGmodtut4 which is the interior of the house. It has three door. One leads to the basement. The other two are linked to the exterior. Lock the exterior doors and set the ownership to our old buddy BGDummyPlayer. Set the interior cell ownership to BGDummyPlayer as well. Add the BGTopViewKey to the house to Blairs inventory. Now create a ’uncertified’ deed and add this to his inventory.

Deed Text.

<font face=5>
<BR>
<BR>
This document hereby states that the bearer is the sole owner and possessor of the
domicile currently known as Top View. Said domicile is located North of the Imperial
City and South of the city of Bruma in the territory known as Cyrodiil.<BR>
<BR>
The bearer has full ownership rights to all of the structures, flora and land within
the property borders as defined in the Tamerial Construction Charter. The bearer is
responsible for all matters pertaining to or occurring on said property.<BR>
<BR>
This document also empowers the bearer transfer rights to reassign the property as he
sees fit. The bearer may amend this document to rename the manor  by submitting the
proper forms and payments to the Tamerial Construction Charter and by filing
duplicate forms with the Documents Division of the Imperial City Archives.
THIS DOCUMENT MUST BE REGISTERED IN THE IMPERIAL CITY BY A QUALIFIED NOTARY PUBLIC TO GAIN LEGAL FORCE.

This document explains why we have to return to the Imperial City.

Both Blair and Brown will need special AI’s to get them to work properly.

I also wanted to make sure the player no matter how good a sneak is forced to confront Blair. How do we do this. Easy we script it. We also have set the adventure up so that you have to kill Blair to move the quest on.

How does the game know he is dead? Scripts of course. We can combine both functions into a single script.

Scriptname BGBlairDeathScript

Short DoOnce

Begin OnDeath

  SetStage BGM001 95

End

Begin GameMode

  If ( GetStage BGM001<95 ) && ( DoOnce == 0 ) 

    If ( Player.GetDistance BGBlairRef <= 500)
      StartConversation Player BGMBlairGreet
      Set DoOnce to 1
    EndIf

  EndIf

End

We now have to set up the conversation. We use the conversation tab rather than the topic tab. Also set this conversation up as a goodbye, to terminate any further discussion.

CONVERSATION	BGMBlairGreet
RESPONSE	You are a fool for coming here. Now prepare to die.
CONDITIONS	GetIsId BGBlair == 1 GetStage BGM001 >= 80
ADD TOPICS	(none)
RESULT SCRIPT	(none)

When the PC kills Blair we can then update the journal

I have killed Blair. I should search his body for the deed and my house key. I should also see if he has a key so I can release Brown. I can then return to the Imperial City to see Vilanus.

We have set the quest up so that as well as the reward of the house the player can also get access to the treasure chest if they get the combination this is dictated by setting up a choices dialogue through Brown.

Initially we set up a greeting.

TOPIC	GREETING
RESPONSE	Please, Please, don't kill me. I just want to get away from here. Please let me go
CONDITIONS	GetIsId BGBrown == 1 GetStage BGM001 >= 95
ADD TOPICS	BgBrownChoice1 BgBrownChoice2
RESULT SCRIPT	(none)

The positive response info for BGBrownC1 gives a stage boost, the negative one does not.

TOPIC	BGBrownC1
RESPONSE	Thank You! Thank you! The code is 1 4 7
CONDITIONS	GetIsId BGBrown == 1 GetStage BGM001 >= 95
ADD TOPICS	(none)
RESULT SCRIPT	SetStage BGM001 100

We update the journal and run a bit of script as a result

Brown has given me the code to the Combination Chest I need to enter the numbers 1 4 7 to unlock it. Once I've done that I will need to go and see Vilanus Villa in the Imperial City. Vilanus will need to transfer ownership of my uncle's house to me.

The script is used to remove the quest object status from a number of items which are no longer needed and which the PC can now dispose of.

SetQuestObject BGHideoutCELLKey 0
SetQuestObject BGHideoutKey 0
SetQuestObject BGBrownLetter 0
SetQuestObject BGPartialLetter 0

TOPIC	BGBrownC2
RESPONSE	Then you'll never learn the entry code.
CONDITIONS	GetIsId BGBrown == 1 GetStage BGM001 >= 95
ADD TOPICS	(none)
RESULT SCRIPT	(none)

We will need to look at altering Browns behaviour for the final release. We will need to add some AI in the next lesson to get him to run away.

What we do need to look at now is another hefty bit of scripting which controls the treasure chest

Again here it is in its entirety. Look through it and try to work out what it is doing.

It controls a chest with a three digit combination style lock.

Scriptname BGCombinationChestScript

Short DigitCount
Short Button1
Short Button2
Short Button3
Short CombiRight
Short ChestOpen
Short GoldCount
Short DoOnce

Begin OnActivate

  If (ChestOpen == 2)
    Activate
  Else
    Set ChestOpen to 1
  EndIf

End

Begin GameMode

;-----------------------------------------------------------
  If (ChestOpen == 1)
;------------------------------------------------------------
    If (DigitCount == 0)
      MessageBox, "Please input the first digit of thecombination",
        "0","1","2","3","4","5","6","7","8","9" ;one line
      Set DigitCount to 1
    EndIf

    If (DigitCount == 1)
      Set Button1 to GetButtonPressed
      If button1 == -1
        Return
      Else
        Set DigitCount to 2
      EndIf
    EndIf

    If (DigitCount == 2)
      MessageBox, "Please input the second digit of the combination",
        "0","1","2","3","4","5","6","7","8","9" ;one line
      Set DigitCount to 3
    EndIf

    If (DigitCount == 3)
      Set Button2 to GetButtonPressed
      If Button2 == -1
        Return
      Else
        Set DigitCount to 4
      EndIf
    EndIf

    If (DigitCount == 4)
      MessageBox, "Please input the third digit of the combination",
        "0","1","2","3","4","5","6","7","8","9" ;one line
      Set DigitCount to 5
    EndIf

    If (DigitCount == 5)
      Set Button3 to GetButtonPressed
      If button3 == -1
        Return
      Else
        Set DigitCount to 6
      EndIf
    EndIf
;---------------------------------------------------------------

    If (DigitCount == 6)
      If Button1 == 1
        Set CombiRight to CombiRight + 1
      EndIf
      If Button2 == 4
        Set CombiRight to CombiRight + 1
      EndIf
      If Button3 == 7
        Set CombiRight to CombiRight +1
      EndIf
    EndIf

;---------------------------------------------------------------

    If (DigitCount == 6) && (CombiRight ==3)
      Set ChestOpen to 2
      Set DigitCount to 0
      Return
    EndIf
;---------------------------------------------------------------

    If (DigitCount == 6) && (CombiRight <= 2)
      MessageBox, "Naughty, naughty. Now take your punishment"
      If (Player.GetItemCount "gold001") >= 100
        Player.RemoveItem "gold001" 100
        BGBlairChestref.AddItem "gold001" 100
        Set DigitCount to 0
        Set ChestOpen to 0
        Return
      Else
        Set GoldCount to Player.GetItemCount "gold001" 
        Player.RemoveItem "gold001" GoldCount
        BGBlairChestref.AddItem "Gold001" GoldCount
        Player.AddItem "gold001" 1
        Set DigitCount to 0
        Set ChestOpen to 0
      EndIf

    EndIf
;-----------------------------------------------------------------
  ElseIf (ChestOpen == 0)
    Return
  ElseIf (ChestOpen == 2)
    If DoOnce == 0
      Set DoOnce to 1
      Activate
      Return
    EndIf
  Else
    Return
  EndIf
End

In this case we control when the script runs using what I call a two block script. The first block sets up the conditions in which the second block works.

Begin OnActivate

  If (ChestOpen == 2)
    Activate
  Else
    Set ChestOpen to 1
  EndIf

End

This first block runs only when the chest is activated. It uses a control variable called ChestOpen.

This in fact has 3 states or values. 0 = Chest has not been activated and the combination is has not been entered 1 = Chest has been activated and the combination has not been entered 2 = Chest has been activated and the combination has been entered correctly The Activate function has to be included to get the chest to open. Note since we will attach this script to the chest we need no reference id.

The first script checks if we have already opened the chest. If so it opens it again. If not it sets the ChestOpen to 1. This enables the GameMode script.

Begin GameMode

We use the Chest Open == 1 to enable the main body of the script.

  If (ChestOpen == 1)

For this we use another variable called DigitCount to help work through the different stages of the script

  If (DigitCount == 0)
    MessageBox, "Please input the first digit of the combination",
      "0","1","2","3","4","5","6","7","8","9" ;should be one line
    Set DigitCount to 1
  EndIf

Note here that the message box statement must all be on one line of code. On some editors the word wrap may make it look like this is on two or even three lines. If you cut and paste, the script editor may pick this up. The PC can now select the first digit.

  If (DigitCount == 1)
    Set Button1 to GetButtonPressed
    If Button1 == -1
      Return
    Else
      Set DigitCount to 2
    EndIf
  EndIf

We then set the value of Button1. We also bump DigitCount up one to enable the next step. If no button is pressed the script halt for that frame only using the return command. We then repeat this process to get the second and third digits.

  If (DigitCount == 2)
    MessageBox, "Please input the second digit of the combination",
      "0","1","2","3","4","5","6","7","8","9" ;again, one line
    Set DigitCount to 3
  EndIf

  If (DigitCount == 3)
    Set Button2 to GetButtonPressed
    If button2 == -1
      Return
    Else
      Set DigitCount to 4
    EndIf
  EndIf

  If (DigitCount == 4)
    MessageBox, "Please input the third digit of the combination",
      "0","1","2","3","4","5","6","7","8","9" ;one line
    Set DigitCount to 5
  EndIf

  If (DigitCount == 5)
    Set Button3 to GetButtonPressed
    If button3 == -1
      Return
    Else
      Set DigitCount to 6
    EndIf
  EndIf

Once Digit count is at 6 we can test to see if the combination is indeed 1 4 7. We use another variable called CombiRight to track this. If this reaches 3 the PC has opened the chest.

  If (DigitCount == 6)
    If Button1 == 1
      Set CombiRight to CombiRight +1
    EndIf
    If Button2 == 4
      Set CombiRight to CombiRight +1
    EndIf
    If Button3 == 7
      Set CombiRight to CombiRight +1
    EndIf
  EndIf

We test that CombiRight is indeed 3. If it is we set the chest open variable to 2, and we reset the digit count to zero to end any further progression.

  If (DigitCount == 6) && (CombiRight ==3)
    Set ChestOpen to 2
    Set DigitCount to 0
    Return
  EndIf

If it fails we want to punish the player for his failure, and nothing hurts quite lick taking a chunk of gold off the PC.

  If (DigitCount == 6) && (CombiRight <=2)

This bit of script displays a message

    MessageBox, "Naughty, naughty. Now take your punishment"[/i]

Then checks that the PC can afford the ‘fine’

  If (Player.GetItemCount "gold001") >= 100

It takes away the gold from the PC and then adds it to the chest. It then resets the control variable so the player can try to open the chest again.

    Player.RemoveItem "gold001" 100
    BGBlairChestref.additem "gold001" 100
    Set DigitCount to 0
    Set ChestOpen to 0
    Return

Of course the player may not have 100 septims, so we use a variable called gold count which we set to the value of the player’s current gold count

    Else
      Set GoldCount to Player.GetItemCount "gold001"

Then we take that away and add it to the chest.

      Player.RemoveItem "gold001" GoldCount
      BGBlairChestRef.AddItem "Gold001" GoldCount
      Player.AddItem "gold001" 1
      Set DigitCount to 0
      Set ChestOpen to 0
    EndIf

  EndIf

Finally we wrap the script up with a couple of brief tidy ups. The first deals with the fact that the game mode block will run every frame while we are in the dungeon cell. Not just the room. Prior to touching the chest the chest open status is 0. If this is so the script returns and does nothing for the frame.

  ElseIf (ChestOpen == 0)
    Return

This bit opens the chest if we have the correct combination.

  ElseIf (ChestOpen == 2)
    If DoOnce == 0
      Set DoOnce to 1
      BGBlairChestRef.Activate Player
      Return
    EndIf
  Else
    Return
  EndIf
End

Now its time to wrap up our little adventure. We move the scene back to the Imperial City

Imperial City Phase Two

Objective: In this phase the player will again meet Vilanus, who will set about transferring the deeds of the property over to you. After 24 hours you can revisit and he will have the documents ready.

We will need

• A second complete deed document
• The Prize House
• A map marker

We begin with another dialogue pair involving Vilanus Villa.

One for before you have the key and deed.

The second for when you are successful.

Again we need to add a small bit of script to the Quest Script to check for this.

  If (Player.GetItemCount "BGM001HouseDeedUC">=1) && (Player.GetItemCount "BGTopViewKey">=1)
    If DoOnce3 ==0
      Set QuestWon to 1
      Set DoOnce3 to 1
    EndIf
  EndIf

TOPIC	GREETING
RESPONSE	I can't help you until you find the key and deed. You have to go back and get the deed and key. Check if Blair has it.
CONDITIONS	GetIsId BGVilanusVilla == 1 GetStage BGM001 >= 80 GetQuestVariable BGM001.QuestWon == 0
ADD TOPICS	(none)
RESULT SCRIPT	(none)

and

TOPIC	GREETING
RESPONSE	Hello, Have you managed to recover the deed and key?
CONDITIONS	GetIsId BGVilanusVilla == 1 GetStage BGM001 >= 80 GetQuestVariable BGM001.QuestWon == 1
ADD TOPICS	none
RESULT SCRIPT	AddTopic BGTopView

(add topic via script to avoid issue with GREETINGS add topic's not appearing in the game)

For the new topic we add several responses. This first info tell the player to come back later

TOPIC	BGTopView (Top View Cottage?)
RESPONSE	Excellent, I will take the deed to the Property Registrar today. Come back tomorrow and I'll complete the transfer.
CONDITIONS	GetIsId BGVilanusVilla == 1 GetQuestVariable BGM001.QuestWon == 1
ADD TOPICS	BGTopView
RESULT SCRIPT	Player.RemoveItem "BGM001HouseDeeduc" 1 SetStage BGM001 110 Stage 110 Journal Update

I have met with Vilanus Villa again. He has taken the deed to Top View and will complete the registration. I should come back in 24 hours to complete the transfer.

We want to set up a delay of one day before we can collect the finished documents. This gives us an excellent opportunity to look at and practice timers

Timers

Timers are another bit of scripting that gets used again and again. The game uses a number of global variables to report the progress of time.

The two most used are

GetSecondsPassed 
GameDaysPassed 

We can use the seconds passed to establish timed events. We must use a float variable to interact with the GetSecondsPassed function.

Ok this example script is really pointless it takes 10 septims from the player, then gives them back 25 seconds later. However, the structure is what counts.

If you change the bits in bold to suit your needs, you will have a perfectly functional timer script.

The Remove function can be replaced with any script you want to run prior to the countdown.

The 25 controls how long the script will run for.

The Add function can be replaced by whatever you want to happen after the event.

Scriptname ExampleTimerScript

float Timer
short DoOnce

Begin GameMode
	
  If SetZero == 0 
    Set Timer to 25
    Set DoOnce to 1
    Player.RemoveItem ‘gold001’ 10
  Else
    If Timer > 0
      Set Timer to Timer - GetSecondsPassed
    Else
      Player.AddItem ‘gold001’ 10
    EndIf
  EndIf

End

When you plan to script longer events where precision is not essential you can use the courser GameDaysPassed function.

In the quest script we add some variables called StartDay, Timer, and DeedDone.

  If(GetStage BGM001 == 110)
    If(Timer == 0)
      Set StartDay to GameDaysPassed
      Set Timer to 1
    EndIf
  EndIf

  If (Timer == 1)
    If (( GameDaysPassed - StartDay ) >= 1 )
      Set DeedDone to 1
      Set Timer to 2
    Else
    EndIf
  EndIf

The timer variable controls which bits of script work.

The DeedDone variable is used to enable dialogue.

The key pair of script lines are

Set StartDay to GameDaysPassed

(( GameDaysPassed - StartDay ) >= 1 )

You replace the number 1 with the number of days you want the event to last.

When the deed has not been completed ( DeedDone == 0) use

TOPIC	BGTopView (Top View Cottage?)
RESPONSE	I haven't quite finished the paperwork check with me later.
CONDITIONS	GetIsId BGVilanusVilla == 1 GetQuestVariable BGM001.QuestWon == 1 GetQuestVariable BGM001.DeedDone == 0
ADD TOPICS	(none)
RESULT SCRIPT	(none)

Once the deed is done you produce this message

TOPIC	BGTopView (Top View Cottage?)
RESPONSE	Congratulations, you are new the proud Owner of Top View. Here is the paperwork. I'll mark it's location on the map for you. May the gods be with you.
CONDITIONS	GetIsId BGVilanusVilla == 1 GetQuestVariable BGM001.QuestWon == 1 GetQuestVariable BGM001.DeedDone == 0
ADD TOPICS	(none)
RESULT SCRIPT	SetStage BGM001 120

and add a Journal Update for Stage 120

Vilanus has completed the paperwork. I should now go visit my new home.

Once again we need to add a mapmarker to the outside of the house. Call it BGTopViewMapMarker.

And the following quest stage result script is then added and complied

Results Script

Player.additem "BGM001HouseDeed" 1
TopViewPlayerDoor1Ref.SetOwnership
TopViewPlayerDoor2Ref.SetOwnership
SetCellOwnership Bgmodtut4
SetCellOwnership Bgmodtu4base
ShowMap BGTopViewMapMarker

This script does the ownership transfer.

It sets the ownership of the two doors, and the two interior cells to the player.

It also adds the finished certified document. Note this document is not a quest item.

We can also add the following as an end of quest reply from Vilanus.

TOPIC	BGTopView (Top View Cottage?)
RESPONSE	I hope you enjoy the house.
CONDITIONS*	GetIsId BGVilanusVilla == 1 GetQuestVariable BGM001.QuestWon == 1 GetQuestVariable BGM001.DeedDone == 1 GetStage BGM001 >= 120
ADD TOPICS	(none)
RESULT SCRIPT	(none)

We then complete the quest script with a final block to check when the PC arrives at the house. Of course we will need

  If (GetStage BGM001 == 120)
    If (Player.GetDistance BGTopViewXMarker <= 300)
      SetStage BGM001 130
    EndIf
  EndIf

This gives a final journal entry. We should also mark the quest as complete using the tab. Remember this does not end the quest. To do that we must use the StopQuest function

I have reached Top View. I am now free to explore my new home.

And finally we add this result script. This removes the essential status from the three essential characters so you can go ahead and kill them now. It boosts the player fame (optional), and finally stops the quest.

ModPCFame 1
SetEssential BGVilanusVilla 0
SetEssential BGMSmith 0
SetEssential BGCptHubart 0
StopQuest BGM001

So there you have it. A complete functional quest.

However, if you really want to wow the public with our release we will need to add some AI to our NPC’s and look at our options regarding Audio and Lip Sync, and that’s is what lesson 8 will be about.

Till Then Happy Modding.

Thanks

Thanks to dtom, who posted the guide on the Elder Scrolls Forums that this article is based on.